ささぴブログ

「おしえて！セカンドライフ！」に上がった
  「テクスチャーの変更（http://oshiete.slmame.com/e296168.html）」
  「長押しクリック（http://oshiete.slmame.com/e293031.html）」
にインスパイアーされて作ってみました。

同じコンテンツ内にあるテクスチャーを表示し、タッチするとテクスチャーが切り替わるという、ありがちなスクリプトですが、ちょっと機能的に寂しいので、「長押し（タッチし続ける）」すると表示テクスチャーを戻す機能を入れました。押しっぱなしにしているとドンドン戻ります。

プリムのコンテンツに表示したいテクスチャーとこのスクリプトを入れます。
先にスクリプトを入れると、コンテンツ内にテクスチャーがないのでエラーになりますが、テクスチャーを入れてからタッチするとリセットされますので、気にしないで作業を続けてください。

リスト変数を使ってテクスチャー名を『管理していない』ので、テクスチャー数が多かったり、テクスチャー名が長かったりしても、メモリーが足りなくなってエラーになったりしません。

だいたいコメントとして書いているので、それを参照してください。

//==================================================
// texture_changer_by_touch
// スクリプトでコンテンツ内のテクスチャー名を自動取得
// コンテンツに変化があればテクスチャー数をチェックし、テクスチャー数に変化があれば最初から表示し直します
// タッチでテクスチャー切り替え
// 「長押し」でテクスチャー切り替え（リバース）
// 「長押し」しっぱなしにしているとどんどん戻ります。
// コンテンツ内にテクスチャーが無い場合はエラーステートに入る
// オーナータッチのみに反応するか、誰にでも反応するか選択可（変数OWNER_ONLY）

// 1.0.0
// 2008/07/07
// created by sasapy Beck

// Define
    integer AVATAR_DROP = TRUE; // 他のアバターのドロップを許可するか
    integer OWNER_ONLY = FALSE; // オーナーのタッチにのみ反応する

    key owner_key = NULL_KEY; // オーナーキー
    key avatar_key = NULL_KEY; // アバターキー

    string texture_name = ""; // テクスチャー名
    integer texture_index = 0; // 表示テクスチャー番号
    integer texture_max = 0; // テクスチャー数

    integer FACE = ALL_SIDES; // 表示する面番号
    vector COLOR = <0.0, 1.0, 0.0>; // テキストの色
    float ALPHA = 1.0; // テキストの透明度

    integer touch_count = 0; // 長押し用カウンター
    integer LONG_PUSH = 20; // 長押し検出閾値（20で約1秒）

//--------------------------------------------------
// Main
    default
    {
        state_entry()
        {
            owner_key = llGetOwner(); // オーナーのキー取得

            llAllowInventoryDrop(AVATAR_DROP); // ドロップの許可

            texture_max = llGetInventoryNumber(INVENTORY_TEXTURE); // テクスチャー数取得
            if(texture_max <= 0) // テクスチャー数が0以下の場合
            {
                llOwnerSay("テクスチャーが見つかりません"); // 表示
                state error; // エラーステートへ
            }

            texture_name = llGetInventoryName(INVENTORY_TEXTURE, texture_index); // テクスチャー名取得
            llSetTexture(texture_name, FACE); // テクスチャー表示
            llSetText((string)(texture_index + 1) + "/" + (string)texture_max + "\n" + texture_name, COLOR, ALPHA); // フローティングテキスト表示
        }

// Touch Event
// タッチ開始
        touch_start(integer total_number)
        {
            touch_count = 0; // カウンター初期化
        }

// タッチ最中
        touch(integer total_number)
        {
            avatar_key = llDetectedKey(0); // タッチしたアバターのキー取得

            if(!OWNER_ONLY || (avatar_key == owner_key)) // タッチしたアバターは有効か？
            {
                touch_count ++; // カウンター更新

                if((touch_count % LONG_PUSH) == 0) // 定数回の剰余が0の場合（毎回）
                {
                    texture_index --; // 番号の更新
                    if(texture_index < 0) // 0より小さくなったら
                    {
                        texture_index = texture_max - 1; // 最大値-1に戻す
                    }

                    texture_name = llGetInventoryName(INVENTORY_TEXTURE, texture_index); // テクスチャー名取得
                    llSetTexture(texture_name, FACE); // テクスチャー表示
                    llSetText((string)(texture_index + 1) + "/" + (string)texture_max + "\n" + texture_name, COLOR, ALPHA); // フローティングテキスト表示
                }
            }
        }

// タッチ終了
        touch_end(integer total_number)
        {
            avatar_key = llDetectedKey(0); // タッチしたアバターのキー取得

            if(!OWNER_ONLY || (avatar_key == owner_key)) // タッチしたアバターは有効か？
            {
                if(touch_count < LONG_PUSH) // 通常のタッチ
                {
                    texture_index ++; // 番号の更新
                    if(texture_index >= texture_max) // 最大値以上になった場合
                    {
                        texture_index = 0; // 0に戻す
                    }

                    texture_name = llGetInventoryName(INVENTORY_TEXTURE, texture_index); // テクスチャー名取得
                    llSetTexture(texture_name, FACE); // テクスチャー表示
                    llSetText((string)(texture_index + 1) + "/" + (string)texture_max + "\n" + texture_name, COLOR, ALPHA); // フローティングテキスト表示
                }
            }
        }

// Change Event
        changed(integer change)
        {
            integer temp_max;

            if((change & CHANGED_INVENTORY) || (change & CHANGED_ALLOWED_DROP)) // インベントリーに変化があった場合
            {
                temp_max = llGetInventoryNumber(INVENTORY_TEXTURE); // テクスチャー数の取得
                if(texture_max != temp_max) // テクスチャー数が変わった場合
                {
                    texture_max = temp_max; // テクスチャー数の更新

                    if(texture_max <= 0) // テクスチャー数が0以下の場合
                    {
                        llOwnerSay("テクスチャーが見つかりません"); // 表示
                        state error; // エラーステートへ
                    }

                    texture_index = 0; // 0に戻す
                    texture_name = llGetInventoryName(INVENTORY_TEXTURE, texture_index); // テクスチャー名取得
                    llSetTexture(texture_name, FACE); // テクスチャー表示
                    llSetText((string)(texture_index + 1) + "/" + (string)texture_max + "\n" + texture_name, COLOR, ALPHA); // フローティングテキスト表示
                }
            }
        }
    }

//--------------------------------------------------
// エラーが発生した場合
state error
    {
        state_entry()
        {
            llOwnerSay("エラーを解消してタッチしてください"); // 表示
        }

        touch_start(integer total_number) // タッチしたら
        {
            llResetScript(); // スクリプトのリセット
        }
    }
//==================================================
青文字：お好みで変更してください